Uboot源码.doc

uboot 源码阅读
这篇文章属于转载
cpu/arm920t/
在开始处首先定义了一个全局的标签,
.globl _start
这个是整个uboot 程序的入口,可在链接脚本board/s3c2410/u- 中找到。
这个标签所指的地址处就是一跳转指令
_start: b reset
开始复位。
reset:
/*
* set the cpu to SVC32 mode
*/
mrs r0,cpsr
bic r0,r0,#0x1f
/* disable IRQ and FIQ, ARM instruct set, supervisor mode. added by BoySKung*/
orr r0,r0,#0xd3
msr cpsr,r0
首先将cpu 设置为supervisor 模式。通过设置cpsr 的低5 位为10011 实现,并禁止IRQ、FIQ。
即cpsr 的第七第六位设置为11.
接着关闭看门狗定时器
ldr r0, =pWTCON
mov r1, #0x0
str r1, [r0]
将看门狗定时器控制寄存器置0。
ldr r0, =CLKDIVN
mov r1, #3
str r1, [r0]
设置FCLK:HCLK:PCLK 为1:2:4, 通过设置CLKDIVN 控制寄存器的HDIVN、PDIVN 值实现不同的
比例
00(1:1:1)
01(1:1:2)
10(1:2:2)
11(1:2:4)
这些然后开初始化cpu
cpu_init_crit:
/*
* flush v4 I/D caches
*/
mov r0, #0
mcr p15, 0, r0, c7, c7, 0 /* flush v3/v4 cache */
mcr p15, 0, r0, c8, c7, 0 /* flush v4 TLB */
首先关闭ICache 和DCache.
/*
* disable MMU stuff and caches
*/
mrc p15, 0, r0, c1, c0, 0
bic r0, r0, #0x00002300 @ clear bits 13, 9:8 (--V- --RS)
bic r0, r0, #0x00000087 @ clear bits 7, 2:0 (B--- -CAM)
orr r0, r0, #0x00000002 @ set bit 2 (A) Align
orr r0, r0, #0x00001000 @ set bit 12 (I) I-Cache
mcr p15, 0, r0, c1, c0, 0
关闭MMU,数据存储格式为小端。开启数据地址对齐错误检测,使能ICACHE。
/*
* before relocating, we have to setup RAM timing
* because memory timing is board-dependend, you will
* find a in your board directory.
*/
mov ip, lr
bl memsetup
mov lr, ip
mov pc, lr
还要对内存时序进行设置,因为内存时序是依赖于开发板的。
Cpu 初始化结束后,开始初始化串口uart
@ Initialize UART
@
@ r0 = number of UART port
InitUART:
ldr r1, =0x50000000
mov r2, #0x0
str r2, [r1, #0x8]
str r2, [r1, #0xc]
mov r2, #0x3
str r2, [r1, #0x0]
ldr r2, =0x245
str r2, [r1, #0x4]
/* 50700000 = PCLK = / 4 = when FCLK at */
#define UART_BRD ((50700000 / (115200 * 16)) - 1)
mov r2, #UART_BRD
str r2, [r1, #0x28]
这里主要对uart 的一些控制寄存器进行了设置,并设置了串口的波特率
mov r3, #100
mov r2, #0x0
1: sub r3, r3, #0x1
tst r2, r3
bne 1b
mov pc, lr
这里是一段延时,具体起什么作用还不清楚。
这些初始化都结束后开始代码重定位
relocate: /* reloca